• 售前

  • 售后

热门帖子
入门百科

SqlServer 垂直分表(减少步伐改动)

[复制链接]
Jacqueline季 显示全部楼层 发表于 2021-8-14 15:19:02 |阅读模式 打印 上一主题 下一主题
  1. 由于sqlserver的设计特殊性,一般大量数据一般都是采用水平分表,而垂直分表只是把text、图片都较大数据放到单独的表中,这样数据设计会更合理,相对于mysql可能要好一点,mssql本来就是一个文件,基本上提升不大,目前来看几十万的数据没有分不分表没有任何影响,对于千万以上数据还是采用水平分表比较好。
复制代码
而 垂直分表 则相对很少见到和用到,因为这大概是数据库计划上的标题了。假如数据库中一张表有部门字段险些从不不更改但经常查询,而部门字段的数据频繁更改,这种计划放到同一个表中就不合理了,相互影响太大了。在已存在改情况的表的时间,可以思量按列拆分表,即垂直拆分。
由于垂直分表的案例比力少,最近因为存在如许的表,以是个人捣鼓了一下。
源表计划布局:
  1. --  源表
  2. CREATE TABLE [dbo].[DemoTab](
  3. [Guid] [uniqueidentifier] NOT NULL,
  4. [UserName] [nvarchar](30) NOT NULL,
  5. [Password] [nvarchar](30) NOT NULL,
  6. [UserAccount] [varchar](30) NOT NULL,
  7. [Amount] [numeric](18, 4) NULL,
  8. CONSTRAINT [PK_DemoTab] PRIMARY KEY CLUSTERED ([Guid])
  9. )
  10. GO
  11. ALTER TABLE [dbo].[DemoTab]
  12. ADD CONSTRAINT [DF_DemoTab_Guid] DEFAULT (newsequentialid()) FOR [Guid]
  13. GO
  14. --  原来是访问视图的(好处就是视图层不变)
  15. CREATE VIEW [dbo].[VDemoTab]
  16. AS
  17. SELECT [Guid],[UserName],[Password],[UserAccount],[Amount]
  18. FROM [dbo].[DemoTab]
  19. GO
复制代码
注:拆分后各表的主键都是相同了,而且拆分后的表是规范化的。
如今拆成两张表:
留意选择一张表作为基表,其他表都有与该表的外键。
  1. --  分表【1】,以该表为"主表",其他拆分出的表为"子表"
  2. CREATE TABLE [dbo].[DemoTab001](
  3. [Guid] [uniqueidentifier] NOT NULL,
  4. [UserName] [nvarchar](30) NOT NULL,
  5. [Password] [nvarchar](30) NOT NULL,
  6. CONSTRAINT [PK_DemoTab001] PRIMARY KEY CLUSTERED ([Guid])
  7. )
  8. GO
  9. --  主键默认值可以不需要,因为插入数据前需要确定主键值
  10. --ALTER TABLE [dbo].[DemoTab001]
  11. --ADD CONSTRAINT [DF_DemoTab001_Guid] DEFAULT (newsequentialid()) FOR [Guid]
  12. --GO
  13. --  分表【2】,"子表"
  14. CREATE TABLE [dbo].[DemoTab002](
  15. [Guid] [uniqueidentifier] NOT NULL,
  16. [UserAccount] [varchar](30) NOT NULL,
  17. [Amount] [numeric](18, 4) NULL,
  18. CONSTRAINT [PK_DemoTab002] PRIMARY KEY CLUSTERED ([Guid])
  19. )
  20. GO
  21. --  主键默认值可以不需要,因为插入数据前需要确定主键值
  22. --ALTER TABLE [dbo].[DemoTab002]
  23. --ADD CONSTRAINT [DF_DemoTab002_Guid] DEFAULT (newsequentialid()) FOR [Guid]
  24. --GO
  25. --  若主表变更主键则级联更新或删除(主键通常是不更新的,也可省去 ON UPDATE CASCADE)
  26. ALTER TABLE [dbo].[DemoTab002]
  27. ADD CONSTRAINT [FK_DemoTab002_DemoTab001_Guid] FOREIGN KEY ([Guid])
  28. REFERENCES [DemoTab001]([Guid]) ON UPDATE CASCADE ON DELETE CASCADE
  29. GO
复制代码
假如之前是对单个表大概视图使用,拆分之后逻辑层改动大概很多,为保持改动最小,可以用连合视图使用。怎么连接表依个人情况而定。
  1. --  拆分后使用联合视图(INNER JOIN 也可以)
  2. ALTER VIEW [dbo].[VDemoTab]
  3. AS
  4. SELECT T1.[Guid],T1.[UserName],T1.[Password],T2.[UserAccount],T2.[Amount]
  5. FROM [dbo].[DemoTab001] T1 LEFT JOIN [dbo].[DemoTab002] T2 ON T1.[Guid]=T2.[Guid]
  6. GO
复制代码
这时标题来了,要对表举行DML使用,insert , update , delete 怎么解决?因为要求主键是分散在多个表而且是相同的!
这时只能用思量触发器来保证同等性了,触发器则界说在视图上,使用的是 INSTEAD OF 范例的触发器。
insert 触发器:
视图 [VDemoTab] 中的 [Guid] 为表 插入时值,在插入触发器中,虚拟表[inserted]的[Guid]是唯一的,以是在触发器中可以同时使用该 [Guid] 插入到多个分表中,保证了多个分表的[Guid]是相同的!
  1. --  insert 触发器
  2. CREATE TRIGGER [dbo].[tgr_VDemoTab_insert]
  3. ON [dbo].[VDemoTab]
  4. INSTEAD OF INSERT
  5. AS
  6. BEGIN
  7. INSERT INTO [dbo].[DemoTab001]([Guid],[UserName],[Password])
  8. SELECT [Guid],[UserName],[Password] FROM inserted;
  9. INSERT INTO [dbo].[DemoTab002]([Guid],[UserAccount],[Amount])
  10. SELECT [Guid],[UserAccount],[Amount] FROM inserted;
  11. END
  12. GO
复制代码
update 触发器:
同理,更新时涉及虚拟表 deleted 和 inserted,而更新是对视图[VDemoTab]更新的,以是虚拟表inserted包括了全部的字段,以是必要触发器分别更新多个分表。
  1. --  update 触发器
  2. CREATE TRIGGER [dbo].[tgr_VDemoTab_update]  
  3. ON [dbo].[VDemoTab]   
  4. INSTEAD OF UPDATE  
  5. AS
  6. BEGIN
  7. UPDATE T1 SET
  8. T1.[UserName] = T2.[UserName],
  9. T1.[Password] = T2.[Password]
  10. FROM [dbo].[DemoTab001] AS T1, inserted AS T2 WHERE T1.[Guid] = T2.[Guid]
  11. UPDATE T1 SET
  12. T1.[UserAccount] = T2.[UserAccount],
  13. T1.[Amount] = T2.[Amount]
  14. FROM [dbo].[DemoTab002] AS T1, inserted AS T2 WHERE T1.[Guid] = T2.[Guid]
  15. END
  16. GO
复制代码
delete 触发器:
删除视图[VDemoTab]记载,涉及多个表则不允许删除,因此只要删除"主表"的记载即可,其他分表都会级联删除。
  1. --  delete 触发器
  2. CREATE TRIGGER [dbo].[tgr_VDemoTab_delete]  
  3. ON [dbo].[VDemoTab]   
  4. INSTEAD OF DELETE  
  5. AS
  6. BEGIN
  7.     DELETE FROM [dbo].[DemoTab001]
  8.     WHERE [Guid] IN (SELECT [Guid] FROM deleted)
  9. END
  10. GO
复制代码
计划根本就完成了,如今举行测试。
  1. INSERT INTO [dbo].[VDemoTab]([Guid],[UserName],[Password],[UserAccount],[Amount])
  2. SELECT NEWID(),'user01','pw01','account01',100
  3. UNION ALL
  4. SELECT NEWID(),'user02','pw02','account02',99
  5. UNION ALL
  6. SELECT NEWID(),'user03','pw03','account03',0
  7. GO
  8. UPDATE [VDemoTab] SET [Password]='pw',[Amount]='10'
  9. WHERE [Amount] >=0 AND [Amount]<100 AND [UserName] LIKE '%3'
  10. GO
  11. DELETE FROM [VDemoTab] WHERE [UserName] = 'user03'
  12. GO
  13. SELECT * FROM [dbo].[DemoTab001]
  14. SELECT * FROM [dbo].[DemoTab002]
  15. SELECT * FROM [dbo].[VDemoTab]
复制代码
根本使用都是正常的!垂直分表完成!
性能怎么样呢?

由于 Guid 作为主键,使用的是 NEWID() 而不是  NEWSEQUENTIALID(),新增记载时聚集索引都大概重新排序较多数据。
分表之后,单个数据页能存储的数据更多了,但是分成多个表中,数据页也增多了,同时 Guid 在每个表都存在,以是查询数据时IO会更多。
对于更新数据,在触发器中是两个表同时更新的,纵然更新此中一个分表,其他分表都会影响。假如分表之后差别时更新,可以在触发器中使用 if(update(col)) 来判断更新的是那一列,就更新相应的基表就行,其他分表不更新。
最好的情况就是,拆分后的表都是“独立”的,不用连合视图,查询和更改都独立,这必要更改逻辑层。

到此这篇关于SqlServer 垂直分表(淘汰步伐改动)的文章就介绍到这了,更多相关SqlServer 垂直分表内容请搜索脚本之家从前的文章或继承欣赏下面的相关文章盼望大家以后多多支持脚本之家!

帖子地址: 

回复

使用道具 举报

分享
推广
火星云矿 | 预约S19Pro,享500抵1000!
您需要登录后才可以回帖 登录 | 立即注册

本版积分规则

草根技术分享(草根吧)是全球知名中文IT技术交流平台,创建于2021年,包含原创博客、精品问答、职业培训、技术社区、资源下载等产品服务,提供原创、优质、完整内容的专业IT技术开发社区。
  • 官方手机版

  • 微信公众号

  • 商务合作