• 售前

  • 售后

热门帖子
入门百科

access下怎样恢复已经删除的记录;怎样恢复已经删除的表、窗体等等对象

[复制链接]
dxf17 显示全部楼层 发表于 2021-8-14 15:19:01 |阅读模式 打印 上一主题 下一主题
题目:

    怎样恢复已经删除的记载;怎样恢复已经删除的表、窗体等等对象
1、我用 DELETE FROM TABLE 删除了一些记载,现在发现误删除了,该怎样恢复?
2、我直接手动删除或者用 DROP TABLE 删除了一个表,现在发现是误删除了,该怎样恢复?
3、我手动删除了一个窗体,该怎样恢复?
4、我删除了记载,可是数据库体积并没有减小,那么是否能找回记载呢?

  


答复:

    1、已经删除的记载是无法恢复的,ACCESS 不是 FOXPRO,MDB 格式不是 DBF 格式,没有逻辑删除和物理删除的概念,一旦删除就无法恢复了。
2、无法恢复,但是你可以检察一下,有没有隐藏的以 "~" 符号开头的表,更改该表的名称有大概找回你须要的表。
3、无法恢复,但是你可以检察一下有没有体系隐藏的对象,有时候对象被删除时体系并不直接删除,而是更改对象名后隐藏它。
4、数据库体积简直没有变小,你压缩修复数据库后体积就会变小了。那是由于在二进制上你的数据简直没有被删除,仍然存放在磁盘的某个扇区,但是微软没有提供 MDB 格式二进制构造方式的参考资料(微软也不会提供,其他第三方公司也没有权利直接反编译 MDB 格式)。至今为止,中国大陆我也没有看到过相关的参考资料。所以目前为止,你已经删除的数据是无法恢复的。但是你可以尝试使用磁盘恢复软件来找到恢复数据的方法,但是该方法不在本文讨论范围。

建议:在创建数据库结构时,可以在各个表中再多加一个 ISDEL 字段,删除记载时不使用 DELETE FROM ,而使用 UPDATE TABLE SET ISDEL=TRUE 如许的语句,然后在界面上不显示 ISDEL=TRUE 的记载即可。
复制代码 代码如下:
如果还没有被压缩理论上可以。试试这段代码吧。加在access模组中
恢復刪除的工作表(未被壓縮)
 
Public Function FnUndeleteObjects() As Boolean
  On Error GoTo ErrorHandler:
  Dim strObjectName           As String
  Dim rsTables                As DAO.Recordset
  Dim dbsDatabase             As DAO.Database
  Dim tDef                    As DAO.TableDef
  Dim qDef                    As DAO.QueryDef
  Dim intNumDeletedItemsFound As Integer
  Set dbsDatabase = CurrentDb
  For Each tDef In dbsDatabase.TableDefs
      'This is actually used as a 'Deleted Flag'
      If tDef.Attributes And dbHiddenObject Then
         strObjectName = FnGetDeletedTableNameByProp(tDef.Name)
         strObjectName = InputBox("A deleted TABLE has been found." & _
                         vbCrLf & vbCrLf & _
                         "To undelete this object, enter a new name:", _
                         "Access Undelete Table", strObjectName)

         If Len(strObjectName) > 0 Then
            FnUndeleteTable CurrentDb, tDef.Name, strObjectName
         End If
         intNumDeletedItemsFound = intNumDeletedItemsFound + 1
      End If
  Next tDef

  For Each qDef In dbsDatabase.QueryDefs
      'Note 'Attributes' flag is not exposed for QueryDef objects,
      'We could look up the flag by using MSysObjects but
      'new queries don't get written to MSysObjects until
      'Access is closed. Therefore we'll just check the
      'start of the name is '~TMPCLP' ...
      If InStr(1, qDef.Name, "~TMPCLP") = 1 Then
         strObjectName = ""
         strObjectName = InputBox("A deleted QUERY has been found." & _
                         vbCrLf & vbCrLf & _
                         "To undelete this object, enter a new name:", _
                         "Access Undelete Query", strObjectName)

         If Len(strObjectName) > 0 Then
            If FnUndeleteQuery(CurrentDb, qDef.Name, strObjectName) Then
               'We'll rename the deleted object since we've made a
               'copy and won't be needing to re-undelete it.
               '(To break the condition "~TMPCLP" in future...)
                qDef.Name = "~TMPCLQ" & Right$(qDef.Name, Len(qDef.Name) - 7)
             End If
         End If
         intNumDeletedItemsFound = intNumDeletedItemsFound + 1
      End If
  Next qDef
  If intNumDeletedItemsFound = 0 Then
     MsgBox "Unable to find any deleted tables/queries to undelete!"
  End If

  Set dbsDatabase = Nothing
  FnUndeleteObjects = True
ExitFunction:
  Exit Function
ErrorHandler:
  MsgBox "Error occured in FnUndeleteObjects() - " & _
         Err.Description & " (" & CStr(Err.Number) & ")"
  GoTo ExitFunction
End Function


Private Function FnUndeleteTable(dbDatabase As DAO.Database, _
                 strDeletedTableName As String, _
                 strNewTableName As String)

  'Module (c) 2005 Wayne Phillips (http://www.everythingaccess.com)
  'Written 18/04/2005
  Dim tDef As DAO.TableDef
  Set tDef = dbDatabase.TableDefs(strDeletedTableName)
  'Remove the Deleted Flag...
  tDef.Attributes = tDef.Attributes And Not dbHiddenObject
  'Rename the deleted object to the original or new name...
  tDef.Name = strNewTableName
  dbDatabase.TableDefs.Refresh
  Application.RefreshDatabaseWindow
  Set tDef = Nothing
End Function

Private Function FnUndeleteQuery(dbDatabase As DAO.Database, _
                 strDeletedQueryName As String, _
                 strNewQueryName As String)

  'Module (c) 2005 Wayne Phillips (http://www.everythingaccess.com)
  'Written 18/04/2005
  'We can't just remove the Deleted flag on queries
  '('Attributes' is not an exposed property)
  'So instead we create a new query with the SQL...

  'Note: Can't use DoCmd.CopyObject as it copies the dbHiddenObject attribute!

  If FnCopyQuery(dbDatabase, strDeletedQueryName, strNewQueryName) Then
     FnUndeleteQuery = True
     Application.RefreshDatabaseWindow
  End If
End Function


Private Function FnCopyQuery(dbDatabase As DAO.Database, _
                 strSourceName As String, _
                 strDestinationName As String)

  'Module (c) 2005 Wayne Phillips (http://www.everythingaccess.com)
  'Written 18/04/2005
  On Error GoTo ErrorHandler:

  Dim qDefOld As DAO.QueryDef
  Dim qDefNew As DAO.QueryDef
  Dim Field As DAO.Field

  Set qDefOld = dbDatabase.QueryDefs(strSourceName)
  Set qDefNew = dbDatabase.CreateQueryDef(strDestinationName, qDefOld.SQL)

  'Copy root query properties...
  FnCopyLvProperties qDefNew, qDefOld.Properties, qDefNew.Properties

  For Each Field In qDefOld.Fields
      'Copy each fields individual properties...
      FnCopyLvProperties qDefNew.Fields(Field.Name), _
                         Field.Properties, _
                         qDefNew.Fields(Field.Name).Properties
  Next Field
  dbDatabase.QueryDefs.Refresh
  FnCopyQuery = True
ExitFunction:
  Set qDefNew = Nothing
  Set qDefOld = Nothing
  Exit Function
ErrorHandler:
  MsgBox "Error re-creating query '" & strDestinationName & "':" & vbCrLf & _
         Err.Description & " (" & CStr(Err.Number) & ")"
  GoTo ExitFunction
End Function

Private Function PropExists(Props As DAO.Properties, strPropName As String) As Boolean
  'Module (c) 2005 Wayne Phillips (http://www.everythingaccess.com)
  'Written 18/04/2005
  'If properties fail to be created, we'll just ignore the errors
  On Error Resume Next
  Dim Prop As DAO.Property
  For Each Prop In Props
      If Prop.Name = strPropName Then
         PropExists = True
         Exit Function ' Short circuit
      End If
  Next Prop
  PropExists = False
End Function

Private Sub FnCopyLvProperties(objObject As Object, OldProps As DAO.Properties, NewProps As DAO.Properties)
  'Module (c) 2005 Wayne Phillips (http://www.everythingaccess.com)
  'Written 18/04/2005
  'If properties fail to be created, we'll just ignore the errors
  On Error Resume Next
  Dim Prop As DAO.Property
  Dim NewProp As DAO.Property
  For Each Prop In OldProps
      If Not PropExists(NewProps, Prop.Name) Then
         If IsNumeric(Prop.Value) Then
            NewProps.Append objObject.CreateProperty(Prop.Name, Prop.Type, CLng(Prop.Value))
         Else
            NewProps.Append objObject.CreateProperty(Prop.Name, Prop.Type, Prop.Value)
         End If
      Else
         With NewProps(Prop.Name)
              .Type = Prop.Type
              .Value = Prop.Value
         End With
      End If
  Next Prop
End Sub

Private Function FnGetDeletedTableNameByProp(strRealTableName As String) As String
  'Module (c) 2005 Wayne Phillips (http://www.everythingaccess.com)
  'Written 18/04/2005
  'If an error occurs here, just ignore (user will override the blank name)
  On Error Resume Next
  Dim i As Long
  Dim strNameMap As String

  'Look up the Unicode translation NameMap property to try to guess the
  'original table name... (Access 2000+ only - and doesn't always exist?!)

  strNameMap = CurrentDb.TableDefs(strRealTableName).Properties("NameMap")
  strNameMap = Mid(strNameMap, 23) 'Offset of the table name...

  'Find the null terminator...
  i = 1
  If Len(strNameMap) > 0 Then
     While (i < Len(strNameMap)) And (Asc(Mid(strNameMap, i)) <> 0)
       i = i + 1
     Wend
  End If
  FnGetDeletedTableNameByProp = Left(strNameMap, i - 1)
End Function

帖子地址: 

回复

使用道具 举报

分享
推广
火星云矿 | 预约S19Pro,享500抵1000!
您需要登录后才可以回帖 登录 | 立即注册

本版积分规则

草根技术分享(草根吧)是全球知名中文IT技术交流平台,创建于2021年,包含原创博客、精品问答、职业培训、技术社区、资源下载等产品服务,提供原创、优质、完整内容的专业IT技术开发社区。
  • 官方手机版

  • 微信公众号

  • 商务合作